VB入门教程

VB入门教程

一、VB概述

Visual Basic （以下简称VB）的前身是QBASIC，语言基础是BASIC。自从微软推出VB后，便成为了程序开发人员的首选工具。据统计，仅在数据库系统开发领域，VB就占了90％的份额。VB是基于对象的可视化程序开发工具，它的优点在于能够快捷、简易地建立Windows应用程序。1998年8月，微软推出了VB 6.0的版本，进一步加强了部件开发的功能。以适用人员来分，可有以下三个版本：

　　1. 标准版 针对一般程序设计人员,适合普通应用系统的开发。

　　2. 专业版 针对专业程序开发人员，它在标准版的基础上提供了对数据库和Internet的支持。

　　3. 企业版 适用于专为企业设计应用软件的程序开发人员。

　　对于一个非计算机专业的PFans来讲，使用VB不需要追求完美的算法和精密的逻辑，而只要充分发挥你的想象力和创造力，就能利用VB开发出各种实用的软件了，不论是小游戏还是大型的客户端/服务器端应用程序，都变得非常简单。

　　二、集成开发环境

可视化编程的一个突出特点就是很多功能都集成在其之中，这就是IDE（Integrated Development Environment），即集成开发环境。IDE是指在相应的开发平台中集成了编辑器、编译连接工具、控件器箱辅助工具。例如在VB的集成开发环境中就包括了以下一些主要元素：工具栏、工具箱、工程管理器窗口、属性窗口、窗体设计器、代码编辑器窗口等，开发人员可以按照自己的编程习惯来配置IDE。

　　虽然IDE为我们提供了便捷的开发环境，但VB是一个面向对象的开发工具，而不同于传统的基于过程的编程工具，所以我们必须明确以下几个概念：

　　●对象：是指可以被当作一个单元的代码和数据的组合，它可以是程序中的窗体或控件，也可以是整个程序。

　　●属性：就是对象具有的性质，以表明对象的状态。

　　●事件：是指发生在对象上的事情。Windows应用程序属于“事件驱动”模式，即只有当事件发生时，程序才会运行。

　　●方法：对象本身包含的函数和过程。

　　● 过程：指事件发生时要执行的代码。

　　● 面向对象编程（OOP）：以对象为核心，支持对象的封装机制、多态机制和继承机制

　　● 事件驱动模式：通过事件的发生来触发不同过程中的代码，以推动程序的进程。

　　三、数据类型

在VB中有丰富的数据类型，以下作一简单的说明：

　　1．数字类型：包括整型（Integer）、长整型（Long）、单精度型（Single）、双精度型（Double）和货币型（Currency）等。例如：Dim intTemp As Integer。

　　2．字节型（Byte）：用来存储二进制数据。例如：Dim bytTemp As Byte。

　　3．字符型（String）：字符型变量可以存储可变长度的字符串，非常方便。例如：Dim strTemp As String。

　　4．布尔型（Boolean）：如果一个变量值包含简单的Yes/No、True/False信息，就可以定义为布尔型变量。例如：Dim bolTemp As Boolean。

　　5．日期型（Date）：专门用来表示时间的数据类型，可以有多种表达方式。例如：Dim datTemp As Date。

　　6．对象性（Object）：对象变量存储的是对象的地址信息，它本身并不是一个对象，但定义为Object类型的变量可以通过赋值语句（Set）指向程序所能识别的任何对象。如：

　　Dim MyDB As Object

　　Set MyDB = OpenDatabase(″C:\VB6\tempDB.mdb″)

　　这样对MyDB进行访问时，实际上就是对Access数据库tempDB进行访问。

　　7．万能的Variant类型：Variant类型变量可以存储先前介绍的所有数据类型，VB会自动执行相应的转换。例如：Dim varTemp As Variant 或Dim varTemp。

　　但是Variant类型变量会耗用更多的系统资源，所以我们并不提倡初学者为了省事而胡乱使用。

　四、范例

好了，介绍了一大堆VB的优点，或许里还有点将信将疑，下面就让我们实战演练一下领略VB的“短、平、快”的优点。

　　运行VB 6，新建一个标准的EXE工程，从工具箱中拖放一个CommandButton控件和Timer控件放在主窗体上，并将Timer的Interval和Enabled属性分别设置为50和False，最后再拖放一个Label控件。

　　双击窗体，打开代码窗口，输入以下代码：

　　Option Explicit

　　 Private Sub Command1_Click() ′单击按钮事件

　　Timer1.Enabled = True ′激活计时器

　　End Sub

　　Private Sub Form_Load() ′窗体启动

　　 Label1.Caption = ″欢迎您进入软件世界！″

′改变标签属性

　　End Sub

　　Private Sub Timer1_Timer()

　　 Label1.ForeColor = RGB(Rnd() ＊ 255, Rnd() ＊ 255, Rnd() ＊ 255) ′使标签与体随机交换颜色

　　End Sub

　　然后运行（按F5键），单击窗体上唯一的按钮，你就可以看到你的第一个标准的Windows应用程序了。

　　总的说来，利用VB可以快速地创建应用程序，避免了令无数初级入门者大感头痛的繁琐的算法设计和逻辑陷阱，是初级入门者的最佳选择，使您能轻松自如地在编程的世界遨游。

VB入门教程之二


刚开始可能会比较枯燥，但不可否认也很重要，所以为了学好VB，我们一定要打好基础。

　　 一、事件

通过上一节的例子，你可能对“面向对象的编程”已经有了一定了解，它是由事件驱动的，对于不同的对象，所能感应到的事件也会不同，譬如说当你把鼠标移进某一区域时就会触发MouseMove事件，这很直观，也容易理解，但也有些事件比较抽象，下面我来对一般的事件进行一下解释。

窗体和图象框类事件
Paint事件：当某一对象在屏幕中被移动，改变尺寸或清除后，程序会自动调用Paint事件。 注意：当对象的AutoDraw属性为True（－1）时，程序不会调用Paint事件。
Resize事件：当对象的大小改变时触发Resize事件。
Load事件：仅适用于窗体对象，当窗体被装载时运行。
Unload事件：仅适用于窗体对象，当窗体被卸载时运行。
2.当前光标（Focus）事件

GotFocus事件：当光标聚焦于该对象时发生事件。
LostFocus事件：当光标离开该对象时发生事件。
注意：Focus英文为“焦点”、“聚焦”之意，最直观的例子是，比如有两个窗体，互相有一部分遮盖，当你点下面的窗体时，它就会全部显示出来，这时它处在被激活的状态，并且标题条变成蓝色，这就是GotFocus事件，而相反，另外一个窗体被遮盖，并且标题条变灰，称为LostFocus事件。上面所说的“光标”并非指鼠标指针。

3.鼠标操作事件

Click事件：鼠标单击对象。
DbClick事件：鼠标双击事件。
MouseDown、MouseUp属性：按下/放开鼠标键事件。
MouseMove事件：鼠标移动事件。
DragDrop事件：拖放事件，相当于MouseDown、MouseMove和MouseUp的组合。
DragOver事件：鼠标在拖放过程中就会产生DragOver事件。
4.键盘操作属性

KeyDown、KeyUp事件：按键的按下/放开事件。
KeyPress事件：按键事件。
5.改变控制项事件

Change事件：当对象的内容发生改变时，触发Change事件。最典型的例子是文本框（TextBox）。
DropDown事件：下弹事件，仅用于组合框（ComboBox）对象。
PathChange事件：路径改变事件，仅用于文件列表框（FileBox）对象。
6.其他事件

Timer事件：仅用于计时器，每隔一段时间被触发一次。
二、属性

每个对象都有它的属性，并且“Name”属性是共有的，有了“Name”属性才可以在程序中进行调用。对于属性，可以在窗体的布局操作中完成，也可以在程序运行中改变，这取决你的需要，但有些属性是只读的，它只能在控件布局时改变。我将在以后的实例中具体介绍各个属性的作用。

　 三、数据类型

学过编程的人都知道大多数的计算机语言都规定了各自的数据类型，VB也不例外。其实，在一个最简单的程序中数据类型是可以不作规定的，也就是说，变量可以使用各种类型，但是在一个复杂的程序里，这样做就很危险，因为很可能给同一个变量赋予了不同的类型，而导致程序出错。所以，为了程序的严谨和便于查看，正确的定义数据类型是必要的。定义数据的另一个原因是，不同的数据占用不同的内存数量，譬如整型（Interger）数据占2字节，而长整型数据占4个字节，定义合适的数据类型，不管你相信不相信，它可以节省内存！

VB常用的数据类型有：整型（Integer，表示-32768至32767之间的整数）、长整型（Long，表示-2,147,483,648至2,147,483,647之间的整数）、实型（Single，表示-3.37E+38至3.37E+38之间的实数）、双精度实型（Double，表示-1.67E+308至1.67E+308之间的实数），字符（String，每个字符占一字节，可以储存0～65,535个字符），布尔（Boolean，只有两个值True/-1，或False/0）。
数据类型的定义方法：
定义变量最简单的方法是用“Dim”关键字，它的语法：
Dim 【变量名】As 【数据类型】

如：Dim Index As Integer

也可以在一行中定义多个变量，如：

Dim Index As Integer , Dim Number As Long

把多个变量定义成同一类型可以写成：

Dim Index , Number As Integer

更可以在定义时进行初赋值：

Dim Index=3

对于常量的定义用Const定义，如：Const CR=255。
为了在程序中便于查阅，我们对变量和常量的写法进行规定，变量一般用小写方式，常量则全部大写。

注意：使用常量的好处，对于程序中经常出现的数值，应设常量等于它，这样一是书写方便，其二，如果要改变该数值，只需改变定义常量的语句值，而不需改变每个语句，提高了效率。

数组的定义类似于变量定义，所不同的是数组需要指定数组中的元素个数，例如：
Dim Array(99) As Integer

这个数组中包含100个元素，下标从0到99。

也可以指定下标的起始值，例如：

Dim IntegerArray(5 to 10) As Long

这个数组含有六个元素，下标从5到10。

还可以定义多维数组：

Dim ThreeD(4,2 to 5,3 to 6) As Long

上例定义了一个三维数组(4×4×4)。

记录的定义
记录定义是把控制权交给用户的方法，它让用户可以定义自己的数据类型，它使用关键字“Type”，方法是：

Type 【数据类型标识符】

<域名> As <数据类型>
<域名> As <数据类型>
<域名> As <数据类型>
…………………………

End Type

例如，定义一个地址数据：

Type Address

Street As String
ZipCode As String
Phone As String

End Type

这个地址数据里包括三个属性，街区、邮政编码和电话，可以把某数据定义成此类型：

Dim MyHome As Address

要调用或改变“MyHome”的值时，类似于对对象的属性的操作：

变量名.域名＝“……”

为了简化书写重复的部分,可以用关键字“With”：

With MyHome
.ZipCode=”100037”
.Phone=”12345678”

End With

VB入门教程之三
一、VB与Basic

VB之所以叫做“Visual Basic”就是因为它使用了Basic语言作为代码，所以它们之间有着千丝万缕的关系，如果学过Basic的话，看到VB的程序结构会感到很亲切。但VB作为新生物，也超越了Basic的限制，有了许多自己的特点：
VB建立了一种新的变量类型――货币型变量，通过使用仅带有二位小数的货币变量，就能避免因使用实型变量而带来的数值积累误差问题。
VB在调用函数（Function）时，必须在函数名后跟一对括号。
VB对白兰地使用范围重新做了规范，在Basic里把隐含变量都当作全局变量，而在VB里对隐含变量都当作局部变量。
VB里的说明语句（Declare），仅支持动态链结库（DLL）的子程序和无变量函数。
使用数组，必须事先用Dim或Redim进行定义。

--------------------------------------------------------------------------------

二、注释语句

在使用注释语句之前必须先了解注释的作用，注释不仅仅是对程序的解释，有时它对于程序的调试也非常有用，譬如说可以利用注释屏蔽一条语句以观察变化，发现问题和错误。以后注释语句将是我们在编程里最经常用到的语句之一。

在VB里，注释语句有两种，一种是用“Rem”关键字，这跟DOS里的批处理文件的用法一样，还有一种是利用单引号“’”，例如：

' Dim a As String 与

Rem Dim a As String 的作用是一致的。


--------------------------------------------------------------------------------

三、长语句的分行

在比较早的版本中，因为没有象C等语言用“；”隔开语句与语句，VB的语句是必须写在一行里的，不过后来版本的VB里如许用分行符“_”把一个长语句分成若干行来存放。

四、条件语句

如果你学过任何一种编程的话，都会知道在程序里控制其流程的有两种语句，条件与循环，VB自然也不例外，其实不管哪种语言，条件和循环的样子都差不多，只不过各有各的规矩罢了。

在条件语句里，我们先来学习“If……Then……”语句。

它的一般语法是：

If <条件> Then

<语句>
<语句>
………

End If

与C 语言不同，VB的条件语句更符合英语的语法，如果Then后面所跟的语句只有一条，可以写成：

If <条件> Then <语句>

而不用End If。

有时我们还会用到

If <条件> Then

<语句>
Else
<语句>

End If

更可以在Else里在嵌套If语句，如：

If <条件> Then

<语句>
Else If
<语句>
Else
<语句>

End If

所有这些可以用一个表格表示：

条件1

True
False

语

句

1
条件2

True
False

语

句

2
条件3

True
False

…

…

…
………………………

条件N

True
False

语句N
语句N＋1


用了过多的Else后你会感到很不方便，而且程序结构也不清晰，所以大多数的语言还有Select语句帮助解决这个问题。

VB里的Select语句的格式是这样的：

Select Case <变量名>

Case <情况1>
……
Case <情况2>
……
Case <情况3>
……
……
……
Case Else
……

End Select

例如：

Select Case a%

Case 1
Print “a=1”
Case 2
Print “a=2”
Case Else
Print “a does not equal to 1 or 2.”

End Select

五、循环语句

循环结构是计算机语言里一种重要的结构，它的应用广泛，最简单的例子是累加器的作用，还可以用于穷举法，更直观的例子是把某件事重复指定的次数，这样就不用把要重复的语句输入多次，而通过循环结构完成，非常方便。

C语言里有一个“for”循环语句，VB里也有“For”关键字，作用也差不多，只是VB的“For”语句更容易理解。它的格式是：

For <循环变量>=<初赋值> To <终值> [Step <步长>]

……
……

Next <循环变量>

在默认情况下，Step被设为“1”，可以省略，Step也可以设为负值，例如：

Dim a=0

For I=1 To 10

a=a+I

Next I

这是一个最简单的累加器的例子，把1到10累加在一起，然后赋值给“a”这样的效果和上面是一样的，只不过是倒着加罢了，请看：

Dim a=0

For I=10 To 1 Step –1

a=a+I

Next I

While语句也是一个很常用的循环语句，它的形式很多。

Do While …… Loop语句
While …… Wend 语句
Do …… Loop While
While后面都跟逻辑条件判断，“Do While …… Loop语句”和“While …… Wend 语句”作用相似，都是先判断While后面的条件是否为“真”，如果为“真”则执行里面的语句，如果为“假”，则退出循环，循环直至条件为“假”终止。“Do …… Loop While ”与前两者的区别在于，它不管条件的真假，都会先执行“Do”后面的语句，也就是说，它至少执行语句一次。

与While用法相似的还有Until语句，它是直至条件为真则终止循环，句式把While上述三个语句的While换成Until即可，但是因为容易记混，所以我建议只用While即可。Until <条件>可以相当于While Not <条件>。

For循环和Whlie循环应当根据适当的环境使用，它们有时也可替换。

六、运算操作

数学运算
＋：加法运算，也适合于字符串的之间的合并运算。
－：加法运算。
*：乘法运算。
/：除法运算。
\：整除运算。
Mod：求余运算。例如：a Mod b表示a被b整除以后的余数。
^：幂运算。A^B表示以A为底的B次方。
关系运算
关系运算也称比较运算，它表示不等式的真或假，VB共提供六种运算符，分别是=（等于），>（大于），<（小于），>=（大于等于），<=（小于等于）和<>（不等于）。

逻辑运算
七、 数据与定义

本标题的内容已经在以前向大家详述过，在这里就不再重复。


--------------------------------------------------------------------------------

八、函数与过程

函数与过程有许多相似的地方，它们之间最大也是最本质的区别就在于，函数有一个返回值，而过程只是执行一系列动作，所以可以简单的把函数理解成为一个变量，而VB中的每个事件都是一个过程，比如Command1_Click()就是一个过程。

因为在程序设计中经常会有重复的地方，所以把它做成一个函数或一个过程，在使用时进行调用，可以节省大量的输入代码的时间，而且使用函数和过程也便于程序的结构化和修改查看。函数和过程都可以有参数，也可以没有参数。。。。

VB入门教程之四
从本节开始我们将正式进入VB的编程世界，但这还仅仅是个开端，要编出功能强大的软件，还要学很多东西，那就要看以后的VB高级教程了，我也得努力学啊！

　　按钮是我们在Windows操作见到最多的控件，它们有着各种各样的功能：“确认”、“取消”、“下一步”等等，这些都是按钮的表现，另外还有很多图形话的按钮，其实它们并没什么不同，所有的按钮都是通过单击（click）事件实现的，只不过是在外表不同罢了。下面就让我们建立一个最简单的按钮，双击工具箱的CommandButton，将在窗体上建立一个按钮，它的缺省名（Name属性）为Command1，我们可以把它改名为cmdExit，把Caption属性设为“退出”，然后双击，按钮填写代码：

Private Sub cmdExit_Click()

Unload Me

End Sub

　　按下F5或者工具条上的播放按钮，运行程序。当你按下退出按钮的时候，就会自动退出程序，原因是当你单击按钮时激活了它的Click事件，执行“Unload Me”语句，使得窗体被卸载。

　　上面举了一个比较简单的例子，下面的例子稍微复杂些：

　　新建窗体，布局控件，包括一个List控件，一个Text控件和两个按钮（Command1和Command2），　（比较简单的程序我们都采用缺省名），对它们属性做如下修改：

List1
Caption＝“请输入你的名字”

Text1
Text＝“”（空字符串)

Button1
Caption＝“复原”

Enabled＝False

Button2
Caption=“清除”


　　把使用Button1的Enabled属性设为False（假），是使程序在初始时，无法单击Command1。按F5，运行程序,复原按钮成为灰色，不可选。

当然现在程序还什么也不能做，下面我们在程序中添加代码：

首先在General里声明全局变量：

Dim StoreString As String '用来储存字符串

※注意：为什么用全局变量？

VB里每一个小过程都相当于一个程序，程序里的变量称为局部变量，是只能在程序内部使用的，而当程序调用结束后，由于从内存中被清除，所以变量储存的值也就消失了，这里的全局变量是用来在过程中传递字符串。

接着填写以下代码：

Private Sub Command1_Click()

Text1.Text = StoreString
Command1.Enabled = False

End Sub

　

Private Sub Command2_Click()

StoreString = Text1.Text
Text1.Text = "" '清除
Command1.Enabled = True

End Sub

　　运行程序。按下“清除”，文本框被清除，按下“复原”，文本有被恢复，许多程序中的Undo/Redo就是利用这个原理实现的，现在知道为什么内存越多越好了吧。

　　我们在把程序修改一下，把Button2删除，Button1的Enabled属性改为True，Caption改为“清除”，填写代码：

Private Sub Command1_Click()

If Command1.Caption = "清除" Then

StoreString = Text1.Text
Text1.Text = "" '清除
Command1.Caption = "复原"

Else

Text1.Text = StoreString
Command1.Caption = "清除"

End If

End Sub

　　同样可以上面的功能，但是却少用了一个控件，控件使用少的程序启动会快些。

　　下面的例子要更加复杂些，大家一定都用过Windows附件中的计算器，它是一个标准的科学计算器，利用VB我们也可以做到，只是没有那么复杂，四则运算而已。

　　先建立一个新的项目文件，里面包含一个Form1的窗体。然后，添加控件，包括一个Text框（Text1），和17个按钮，这17个按钮使用的名称都是Command1，只是Index属性不同，就好象一个数组，创立一组按钮的方法是，先在窗体上建立一个按钮（Command1），然后在Command1上击鼠标右键，选择复制（Copy），然后在窗体上任意部位击右键，选择粘贴（Paste），系统会提示是否创建控件组，选择“是”，重复上面步骤，直至创立17个按钮为止。各控件属性如下表：

Text1
BackColor＝&H00C0FFFF&

Text＝“0.”

Command1
Index 0――16

Index 0――9 Caption=“0”－“9”

Index 10 Caption=“.”

Index 11 Caption=“=”

Index 12 Caption=“+”

Index 13 Caption=“-”

Index 14 Caption=“×”

Index 15 Caption=“÷”

Index 16 Caption=“清除”


　　如果想改变一些其他的属性，比如字体，可以自己定义一下Font属性，如果相对多个控件的共同属性进行改变，可以在窗体上按下鼠标，拖动，把多个控件一起选定，然后对它们的共同属性进行修改。

　　别看这个东西小，还费了近我两个小时呢，不觉大叹手生，里面也有些地方很绕弯子，我尽量解释清楚。

　　在编写程序之前，我们先来回顾一下计算器的使用。

按下数字键在液晶屏上会出现数字，这是最基本的功能。
第一次按下运算键，再按下数字键，将重新输入第二个数字，再次按下运算键，将算出前两个数的结果，然后按下数字键，将又重新输入新的数字。
输入数字后，按下“等于键”将仍输出原来的数字，输入运算符和第二个数字后在按下“等于”，将得到二者的结果。然后又重复第二、三步。
按下“清除”，数据被全部清除。
　　了解了这些，我们一步一步实现。

　　先实现数据的输入，请看代码。

　　与未创立组的控件相比，它的事件里多了Index参数，组里所有的对象都使用同一个事件。

　　先在General里声明窗体级全局变量：

Dim Num1, Num2 As Single
Dim StrNum1, StrNum2 As String
Dim FirstNum As Boolean '判断是否是数字开头

　　因为Text1里是存放字符串的，所以要把输入的数据进行运算，必须把字符型变量转变为实型变量，分别用Num1、Num2和StrNum1、StrNum2进行存放。

　　在Form_Load事件里给变量初赋值：

Num1 = 0
Num2 = 0
StrNum1 = ""
StrNum2 = ""
FirstNum = True

　　因为17个按钮使用的是同一事件，所以我们用一个Select Case语句区分各个按钮，双击任意按钮输入代码：

Private Sub Command1_Click(Index As Integer)

Select Case Index

Case 0 To 9

If FirstNum Then

StrNum1 = Str(Index)’实型转字符型
FirstNum = False’初赋值为假

Else’非初赋值

StrNum1 = StrNum1 + Str(Index)

End If

Text1.Text = StrNum1’显示

<还有其他语句，等待插入>

End Select

End Sub

运行程序的话已经可以输入数据，下面我们来处理小数点。

在General里声明新的变量：

Dim PointFlag As Boolean '判断是否已有小数点

我们知道小数点只能输入一次，一个数据中不能有多个小数点存在，所以需要一个布尔变量做判断。

在Form_Load里进行初赋值：

PointFlag = False

在Command的单击事件里接着上面输入新的代码：

Case 10

If Not PointFlag Then’如果没有小数点

If FirstNum Then’如果是第一个字符

StrNum1 = "0."
FirstNum = False

Else

StrNum1 = StrNum1 + "."

End If

Else’已有小数点

Exit Sub’则退出单击事件

End If

PointFlag = True
Text1.Text = StrNum1

VB入门教程之五
下面会复杂一些，我们先跳过等号，而来处理四则运算：

先在General里声明新变量：

Dim Runsign As Integer '储存运算符号

Dim SignFlag As Boolean '判断是否已有运算符号

然后在Form_Load中进行初赋值：

Runsign = 0

SignFlag = False

在接下的Command1_Click中继续输入代码：

Case 12 To 15

FirstNum = True’使下一次可以输入新数据
PointFlag = False
'还原标记值

If SignFlag Then’前面已有运算符未运算

Call Run

Else

SignFlag = True
StrNum2 = StrNum1’把字符串1复制给字符串2
StrNum1 = ""’字符串1清空

End If

Runsign = Index - 11 ‘储存键入的运算符

　　里面运算的部分我用了一个过程，是因为在按下等号时还会调用到运算过程，这样可以减少代码的输入，也使程序便于浏览。建立过程（Procedure），可以在General部分直接输入，也可以通过菜单里的“Add Procedure”添加。Run的代码如下：

Sub Run()

Num1 = Val(StrNum2)
Num2 = Val(StrNum1)

Select Case Runsign

Case 1’加

equal = Num1 + Num2

Case 2’减

equal = Num1 - Num2

Case 3’乘

equal = Num1 * Num2

Case 4’除

equal = Num1 / Num2

End Select

StrNum2 = Str(equal)
StrNum1 = StrNum2
Text1.Text = StrNum2

End Sub

下面是其余的代码：（在Command1_Click事件里，接着写)

Case 11

If Not SignFlag Then

Text1.Text = StrNum1
equal = Val(StrNum1)
FirstNum = True
PointFlag = False

Else

Call Run
SignFlag = False

End If

Case Else’清除按钮

Call ClearData

里面又用到了一个ClearData过程，实际上就是Form_Load里的变量初赋值，代码如下：

Sub ClearData()

Num1 = 0
Num2 = 0
StrNum1 = ""
StrNum2 = ""
FirstNum = True
PointFlag = False
Runsign = 0
SignFlag = False
Text1.Text = "0."

End Sub

这样完整的程序就完成了，以上介绍了VB的第一个控件——按钮，并且举例，希望你继续看下一节——菜单。



下面给出完整的程序代码：

Dim Num1, Num2 As Single

Dim StrNum1, StrNum2 As String

Dim FirstNum As Boolean '判断是否是数字开头

Dim PointFlag As Boolean '判断是否已有小数点

Dim Runsign As Integer '储存运算符号

Dim SignFlag As Boolean '判断是否已有运算符号

　

Sub ClearData()

Num1 = 0

Num2 = 0

StrNum1 = ""

StrNum2 = ""

FirstNum = True

PointFlag = False

Runsign = 0

SignFlag = False

Text1.Text = "0."

End Sub

　

Sub Run()

Num1 = Val(StrNum2)

Num2 = Val(StrNum1)

Select Case Runsign

Case 1

equal = Num1 + Num2

Case 2

equal = Num1 - Num2

Case 3

equal = Num1 * Num2

Case 4

equal = Num1 / Num2

End Select

StrNum2 = Str(equal)

StrNum1 = StrNum2

Text1.Text = StrNum2

End Sub

　

Private Sub about_Click()

MsgBox "Create by MeToo工作室。2001/8/20", vbDefaultButton1, "VB入门教程之五范例"

End Sub

　

Private Sub Command1_Click(Index As Integer)

Select Case Index

Case 0 To 9

If FirstNum Then

StrNum1 = Str(Index)

FirstNum = False

Else

StrNum1 = StrNum1 + Str(Index)

End If

Text1.Text = StrNum1

Case 10

If Not PointFlag Then

If FirstNum Then

StrNum1 = "0."

FirstNum = False

Else

StrNum1 = StrNum1 + "."

End If

Else

Exit Sub

End If

PointFlag = True

Text1.Text = StrNum1

Case 12 To 15

FirstNum = True

PointFlag = False

'还原标记值

If SignFlag Then

Call Run

Else

SignFlag = True

StrNum2 = StrNum1

StrNum1 = ""

End If

Runsign = Index - 11

Case 11

If Not SignFlag Then

Text1.Text = StrNum1

equal = Val(StrNum1)

FirstNum = True

PointFlag = False

Else

Call Run

SignFlag = False

End If

　

Case Else

Call ClearData

　

End Select

End Sub

　

Private Sub Form_Load()

Call ClearData

End Sub



补充说明

按钮还有两个重要的属性Default（默认属性）和Cancel（取消属性），两个属性都以布尔赋值，把Default设为True，则在按下回车键时，不论焦点处于何处，都会触发该按钮的Click事件，而当Cancel属性被设为True，在按下ESC键时，该按钮的Click属性发生。下面举个例子：

建立一个新窗体和两个按钮，Name属性分别为cmdOK和cmdCancel，把前者的Default设为True，后者的Cancel设为True，Caption属性分别为OK和Cancel。填写代码后运行：

Private Sub cmdCancel_Click()

MsgBox "Cancel按钮被按下", vbDefaultButton1, "提示"

End Sub

　

Private Sub cmdOK_Click()

MsgBox "OK按钮被按下", vbDefaultButton1, "提示"

End Sub

运行。

快捷键大家一定都知道，在VB如何实现呢。其实很简单，在刚才的例子里在建立一个按钮Command1，把它的Caption属性设为Click &ME，在M的下面有一条下划线，运行程序，当你按下Alt+M的时候就触发了Command1_Click事件：

Private Sub Command1_Click()

MsgBox "Click ME 按钮被按下", vbDefaultButton1, "提示"

End Sub

据我所知，有许多用户有使用快捷键的习惯，注意细节上的问题能够使将来你的程序得到更多人的欣赏，不是吗？

VB入门教程之六
我们经常在Windows操作里遇到各种各样的菜单，菜单的操作把各种命令结构化、分分类化，也节省了命令所占的空间，从作用上来讲，菜单类似于按钮，但它只有一个事件——Click。

　　VB作为Windows下的可视编程工具，菜单的设计当然很容易实现，VB3.0按下Ctrl+M，VB4.0以上的版本请按下Ctrl+E，便可呼叫出菜设计的窗口，无论VB的版本，这个窗口的样式是大同小异的。

　　前面说过，菜单相当于简单的按钮，它有几个属性，其中的大部分我们都曾经见过，包括Name、Caption、Index、Checked、Enabled、Visible、快捷键和热键等等。其中Name是必须的。下面请跟我一起设计第一个菜单。

　　首先在Caption添入“文件”，Name为“mnuFile”，按下Next按钮，这样就建立了第一级菜单，注意菜单设计窗口的左中有四个箭头，按下向右的箭头，出现了一排小点，在VB里这叫缩排，这样就可以开始建立第二级菜单。

小知识：实际上我们在生活就中经常用到缩排，写文章时开头要空两格就是一种缩排，在编写程序时更需要缩排，这样使程序结构化，便于观察，当然菜单设计里的缩排有更多的用处。

接着填写下一菜单项，Caption为“新文件”，Name为“mnuFileNew”，按下Next键。

小知识：VB一共如许建立6级子菜单，尽量不要建立这样的菜单，要知道藏在越深处的菜单项越难以被人发现，一个友好的程序界面应该让用户马上找到需要的命令。

　

接着重复以上步骤，创建以下三个菜单项：

Caption 保存

Name mnuFileSave

Level 1

Caption 另存为

Name mnuFileSaveAs

Level 1

Caption 载入

Name mnuFileLoad

Level 1


　

　　我们在菜单里还经常看到把不同项分开的分隔条，在VB里也很容易做到，把Caption设为“-”（减号），Name为mnuBar1。最后增加这个菜单条的最后一项，Caption为“退出”，Name为mnuFileExit。现在可以退出菜单设计窗口。

　　怎么样，经过几章的学习，是不是觉得Windows世界也不是那么神秘？也对，也不对。的确，我们很轻易的实现了这么多的功能，但如果你仔细想想，我们的程序还什么也不会做呢！可以说是徒有其表，要实现强大的功能，恐怕要学很长很长时间，而现在仅仅是个开头，并不是想入非非的时候，我们还要继续努力！

　　现在再次按下Ctrl+E，重回菜单设计窗口，接着添加菜单。（按下向左的箭头，可以使菜单上升一级，Level代表菜单的级别），根据下表添加新的菜单项：

Caption 编辑

Name mnuEdit

Level 0

Caption 剪切

Name mnuEditCut

Level 1

Short-Cut Ctrl+X

Caption 复制

Name mnuEditCopy

Level 1

Short-Cut Ctrl+C

Caption 粘贴

Name mnuEditPaste

Level 1

Short-Cut Ctrl+V

Caption 关于

Name mnuAbout

Level 0


　

　　其中Short-Cut就是平常我们说的热键，你可以在菜单设计窗口中找到，设置一个你需要的组合键，这样不论窗口的焦点处于何处，菜单在第几层，只要按下热键，就相当于调用了该项的Click事件。

　　从Win95以来程序里引入了鼠标右键功能，使鼠标有了更大的用处，在VB里我们也很容易实现。

　　打开Form_MouseDown事件，该事件有两个参数：Button，当按下左键时Button返回1，当按下右键时Button返回2，；Shift，是指在点击鼠标时按下的键盘键，如Shift、Ctrl、Alt，这些我们将在以后讨论，但很难避免在一章中不涉及到不该涉及的内容，学习时有个大概的理解即可。下面在该事件里添加代码：

Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)

If Button = 2 Then

PopupMenu mnuEdit, vbPopupMenuLeftAlign

Else

Exit Sub

End If

End Sub

在上面的代码中我们用到了PopupMenu方法，它的语法是：

object.PopupMenu 菜单名，标记，X坐标，Y坐标

标记是用来表明弹出菜单位于鼠标指针位置的，它有三个值：

vbPopupMenuLeftAlign
位于鼠标左

vbPopupMenuRightAlign
位于鼠标右

VbPopupMenuCenterAlign
位于鼠标中部


　

X、Y值可以用来制定菜单弹出的位置，可以省略。

关于菜单的Visible、Enabled等属性请自己尝试。

VB入门教程之七
我们为什么要设计计算机程序呢，当然是为了计算机能为我们完成工作，但是要完成不同的任务，我们就必须对计算机下达命令，然后计算机在把信息反馈回来——任务是否完成。以上就是所谓的人机对话或交互功能，尤其是在Windows操作里我们需要进行更多的输入工作，我们需要填写各种各样的表格，设置程序的重要参数，把数据输入给计算机，再又它完成既定的工作就是今天我们本章要重点讨论的问题——在VB中如何建立完整的输入机制。

　　在VB中提供了一个函数InputBox能帮助我们建立一个最简单的输入窗体，语法如下：

InputBox（prompt[,title][,default][,xpos][,ypos][,helpfile,context]）

该函数返回一个字符串表达式，其参数含义为：（“[]”表示可缺省）

prompt――字符串表达式，最大长度为1024字符，窗体上的提示部分。

Title――字符串表达式，显示标题栏里的文本。

Default――字符串表达式，窗体中文本框的缺省值。

xpos，ypos――数值表达式，以Twips为单位指定窗体出现在屏幕上的位置。

helpfile――字符串表达式，是帮助文件的完整路径。

Context――数值表达式，指定适合的帮助主题。

可能你看了上面的说明并不明白，那么下面我们就用Input语句完成一个最简单的程序。

　

　　新建一个项目（project），在Form_load里填写一行代码：

a$ = InputBox("举荐你最欣赏的网站", "最佳网站投票", "VB小驿")’

　　按下F5运行程序，在Form1出现之前先会弹出一个输入对话框。这时，无论你按下OK还是Cancel都是没有区别的，因为我们并没有对输入数据进行处理，下面我们完成一个更加复杂些的程序。

新建一个项目文件，把下列控件布局窗体，各对象属性如下表：

Form1
Caption “最佳网站投票演示”

BorderStyle 3’不可调整大小

ControlBox 0’False

Frame1
Caption “输入框属性“

Label1
Autosize 1’True

Index 0至5

0至5 Caption “提示语句”

“标题”

“缺省网站”

“X坐标”

“Y坐标”

“”

Index 4 Enabled False

Index 4 Enabled False

Text1
Text “”’（空字符串）

Index 0至4

Index 3 Text 0

Index 4 Text 0

Check1
Caption “指定输入框位置”

Button1
Index 0,1

Index 0 Caption “显示输入框”

1 Caption “退出程序”


　

　　本例中出现了一个Frame1控件，它是一种框架，可以用来把窗体分成好几个部分，首先应该在窗体上画出Frame1控件，然后再选择相应的控件，在Frame1上描出轮廓，使其是出现在Frame1之上，本例中除去两个按钮，其余都在Frame1上面。本例中用到了几组控件数组，其创建方法是，在选定的点右键，选择Copy，再在窗体其他部位单击右键，选择Paste即可，注意，若要使粘贴的对象在Frame1上，请在Frame1上单击右键选择Paste。

　　我们通过这个窗体，对输入框进行完整的控制，原理是这样的：当我们把窗体中要填写的对输入框的参数完成后按下OK按钮，就会出现我们设计的那个输入框，我们从输入框退出时则返回我们投票的结果，代码如下.

　　窗体初次被装入时，Label1(3)、Label(4)和Text1(3)、Text1(4)的Enabled属性都是False，我们需要通过改变Check1的value（1，被选中，0，未选中）是他们有效或无效。

声明全局变量（General）：

Dim PosChk As Boolean '检查X、Y坐标是否有效

Check1_Click 事件：

Private Sub Check1_Click()

If Check1.value = 1 Then

Label1(3).Enabled = True

Label1(4).Enabled = True

Text1(3).Enabled = True

Text1(4).Enabled = True

PosChk = True

Else

Label1(3).Enabled = False

Label1(4).Enabled = False

Text1(3).Enabled = False

Text1(4).Enabled = False

PosChk = False

End If

End Sub

接着在按钮中填写代码：

Private Sub Command1_Click(Index As Integer)

Dim Prompt, Title, Default As String

Dim xPos, yPos As Integer

Select Case Index

Case 0

Prompt = Text1(0).Text

Title = Text1(1).Text

Default = Text1(2).Text

If PosChk Then

xPos = Val(Text1(3).Text)

yPos = Val(Text1(4).Text)

a$ = InputBox(Prompt, Title, Default, xPos, yPos)

Else

a$ = InputBox(Prompt, Title, Default, xPos, yPos)

End If

Label1(5).Caption = "谢谢您的投票，您的选择是" & a$ & "！"

Case 1

Unload Me

End Select

End Sub

按下F5运行程序，你会看到结果。是不是有种受骗的感觉，啊哟哟，可不是我的错，就是这么容易嘛！

　　从刚才的例子里，我们接触了一些VB中的输入方法，其实数据输入不仅仅局限于向Text框中输入数据，数据的输入还有许多其他的方法，譬如前面的Check1也是向程序发出一定的信息，只要是通过操作向计算机发布命令就可以叫做输入，下面我们来一一介绍。

　　首先要介绍的当然是输入用到最多的Text框。Text没有Click事件，它的缺省事件是Change，也就是当Text框里的一旦内容改变就会激发该事件发生，还是让我们用实例说话吧。

　　Text有几个特殊的属性，一是MultiLine（多行）属性，MultiLine属性为False的时候，不论文本有多长，它都会在一行里显示下去，换行符无效，当它为True的时候，字符串显示到Text框边缘的时候就会自动换行。另一个与之配合的属性是ScrollBars属性，它有4个值，0到3，分别是没有滚动条，水平滚动条，垂直滚动条，和二者都有，它是一个只读属性，也就是说只有在程序设计过程中才能改变，而不能在程序运行中改变，但是我们可以通过API解决运行中改变的问题，我们放在以后再讲。PasswordChart属性，我们经常在程序操作中遇到要填写密码的部分，为了保密起见，在屏幕上显示的字符一般“*”表示，并且这时是无法用剪贴板的，这在VB中非常容易做到，把PasswordChart中设一个用来代替字符串的字符即可，并不一定是“*”哦。

　　下面我们完成一个有趣的小程序，是我以前遇到过的一个程序，我对其进行了部分修改。程序的意思是这样的，假设你是一个司机应超速被警察扣留，现在需要你向警察陈述你的理由，如果你的话能打动他，就可以免交罚金，如果你在规定的字数里没有说出什么有震撼力的话，那老兄你可就惨了，交钱吧。J

　　这个程序比原来的英文程序有了几点不同，第一，由于用到的是双字节中文的中文，所以对于检测中文字符和英文有很大不同，第二，原来的英文程序不管你说多少，警察依然是依法从事，本例中给了犯规者10%的免罚机会（有点无聊……L ，不过也是为了学一些东东嘛）。下面就跟我来设计窗体吧。

Form1
Icon Stop图标

Caption 停车检查

BorderStyle 3

Label1
Caption 警官，我超速是有原因的,请听我说：

BackColor &H00808080&

ForeColor &H80000012&

Label2
Caption 你必须在30字之内完成你理由的申诉，否则将受到罚款！

BackColor &H00808080&

ForeColor &H00FF0000&

Text1
MultiLink True

Text “”

Picture1
Autosize True

BackColor &H00808080&

Visible True

Picture2
Autosize True

BackColor &H00808080&

Visible False

Picture3
Autosize True

BackColor &H00808080&

Visible False

Command1
Visible False


　　三个图片框Picture1－3的Picture属性分别为绿灯，黄灯和红灯，这些图标在VB目录下的\Common files\Graphics\Icons\Traffic下（VB6），你还可以为Label1在Font属性里选一个合适的字体和字重。下面我们来看代码：

首先初始化程序：

Private Sub Form_Load()

'把Command1放在水平的中央

Command1.Top = Label2.Top＋200

Command1.Left = (Form1.Width - Command1.Width) / 2

'重叠三个图片框

Picture2.Left = Picture1.Left

Picture2.Top = Picture1.Top

Picture3.Left = Picture1.Left

Picture3.Top = Picture1.Top

End Sub

　　下面我来讲一讲程序是怎样运行的，我们将用到Text的Change事件，每当字符串改变一次就对它进行一次检查，算出已经说的字数，当字数超过10时，下面的红绿灯会变成黄色，并且在这时随机抽取一个数，它在一个范围内出现的可能是10%，如果在这个范围内就可以免交罚金，如果不在范围则继续，当文字超过20的时候，红绿灯会变成红色，再一次抽取随机数字，步骤同上，如果30个字已满，再进行一次检查，如果你真的那么不幸就该罚款了。

　　程序的步骤清楚了，我们在来看看程序的要点。由于中文是双字节字符，也就是说一个汉字占两个ASC码的位置，而VB显然是为英语国家设计的用Len函数无法返回汉字字节，也就是说一个汉字和和一个ASC字符在Len函数中得到的值是一样的，这就需要特殊处理。用Asc（）函数，在括号内放入一个ASC字符或字符串，它会把第一个ASC码转化为0－255的数值，而把一个汉字放入，它的值必然不在0－255，这也就可以作为判定汉字的基础。我们可以把英文算作半个汉字。

VB入门教程之八

　　下面我们来看看代码：

在General 里声明窗体级变量：

Dim Level As Integer

　

Private Sub Command1_Click()

Unload Me

End Sub

　

Private Sub Text1_Change()

Dim StrLength As Integer’字符串长度

Dim RandomNum As Single’随机数

Dim Str1 As String

Dim a As String

Dim i, Temp

StrLength = 0’每次开始时把字符串长度还原为0

a = Text1.Text

For i = 1 To Len(a)’Len(a)代表字符串的长度

Temp = Asc(Mid$(a, i, 1))’挨个取字符

If Temp > 255 Or Temp < 0 Then’不是ASC码

StrLength = StrLength + 2

Else

StrLength = StrLength + 1

End If

Next i

　

StrLength = StrLength / 2

Select Case StrLength

Case 0 To 9

Picture1.Visible = True

Picture2.Visible = False

Picture3.Visible = False

Label2.Caption = "慢慢说。你还有" & Str(30 - StrLength) & "个字可以说"

Level = 1

Case 10 To 19

If Level = 1 Then

RandomNum = Rnd * 10’得到随机数

If RandomNum <= 10 And RandomNum > 9 Then

Text1.Enabled = False

Label2.Caption = "很抱歉这是个误会……"

Command1.Visible = True

Command1.Caption = "您可以离开了"

End If

Level = 2

Else

Picture1.Visible = False

Picture2.Visible = True

Picture3.Visible = False

Str1 = "怎么还没说完！"

Label2.Caption = Str1 & "你还有" & Str(30 - StrLength) & "个字可以说"

End If

Case 20 To 29

If Level = 2 Then

RandomNum = Rnd * 10

If RandomNum <= 10 And RandomNum > 9 Then

Text1.Enabled = False

Label2.Caption = "很抱歉这是个误会……"

Command1.Visible = True

Command1.Caption = "您可以离开了"

End If

Level = 3

Else

Picture1.Visible = False

Picture2.Visible = False

Picture3.Visible = True

Str1 = "我已经不耐烦了！"

Label2.Caption = Str1 & "你还有" & Str(30 - StrLength) & "个字可以说"

End If

Case Else

Text1.Enabled = False

Label2.Caption = "你已经没有机会了！"

Command1.Visible = True

Command1.Caption = "交钱吧，肇事犯！"

End Select

End Sub

　

中间有几个函数需要解释一下：

Mid可以从字符串中取出一部分，返回字符型，格式:

Mid(字符串,从第几个字符开始,取字符的长度)

Asc可以把字符转换为ASCII码，格式：

Asc(字符串)

Rnd，取得大于0但小于1 的数值，可以没有参数。

　　怎么样，十分简单吧，我们将在下一次继续讨论VB的输入机制！

　　在继续上面的内容时，我想再回顾和强调几个在字符串操作中经常函数：

　　先是几个已经接触过的，Mid()，Asc()，Len()，它们的语法分别是：

Mid(字符型，起始字符，长度)

　　返回子字符串，如果从字符串的第一个字符取起，起始字符为1，依此类推。

Asc(字符型)

　　返回数值，如果参数不是一个字符，而是字符串（多个字符），将返回参数的第一个字符ASCII值。

Len(字符型)

　　返回字符串的长度。

　　下面我再为你解释几个新的函数：

Left(字符串，长度)

　　将返回字符型，从字符串的第一个字符向左取字符串，与之相对应的是Right()，它将从字符串的最后一个字符向右取字符串。

Chr(数值型)

　　该数值范围从0－255，返回字符型，如Chr(65)可返回字符“A”，这样可以输入一些用键盘无法输入的字符。

Str(数值型)

　　该函数把数值型转换为字符型，也许你觉得数值“123”和字符串“123”没什么区别，但在内存中一个ASCII字符是占一个字节，也就是说字符串“123”占3个字节，而当数值“123”是整型时，它占两个字符，当它是长整型时，占4个字节。与之向对应的是Val(数值型)，它把数值型转换为字符型。

　　上面的函数都是以后要经常用到的，请将它们熟悉。

　　上次讲到文本框的用处，还有意思吗？你是否能把上次的程序稍稍变动一下，来计算出输入的单词数，提示一下，单词与单词之间是用空格分隔开的。

　　输入不仅仅是向文本框输入字符，凡是从外界向程序传递数据都可以叫做输入，我们一一说明白。

　　无线钮，记得我们曾在第二节中完成过我们的第一个程序――“Hello World！”它就是一种输入的方法，在设计VB程序时可以通过一组这样的无线钮，它们之间互相排斥，也就是说，只能有一个按钮被选中。它因为很象无线电收音机上的按钮因而得名无线钮。如果要在一个窗体内放置多组无线钮必须用Frame控件把它们区分开来。下面我们在来完成一个例子，顺便熟悉一下另外两个处理字符串的函数――LTrim()和Rtrim()，它们分别用来删除字符串左边的空格和右边的空格，让我们看看它们是如何工作的。

　

　　由于程序窗体比较简单，无需修改更多的属性，一共有三个文本框（Text1到3），分别用来显示输入字符，显示把空格换成星号的字符，和经过处理的字符，还有三个无线钮（Option1到3），要修改的只有Caption属性，分别是“删除左边的空格”、“删除右边的空格”和“删除两边的空格”。因为空格在我们在文本框中无法看到空格，所以我们通过一个称作AddStar的函数把原有字符串中的空格转换为星号，使我们能够看到函数的效果。下面在程序中添加代码，首先在General中声明窗体级变量：

Dim LTrimmedword$, RTrimmedword$ '删除左边空格和右边空格后的字符串

Dim LRTrimmedword$ '删除两边空格后的字符串

　　然后，我们通过一个叫做addstar的函数为字符串加上星号，以前曾说过函数与过程的分别，函数会返回一个函数值，所以addstar也就相当于一个变量，其实这很好理解，就象中学代数中的函数，函数就相当于变量Y，而函数中的参数则相当于自变量X，当然可能有很多自变量X1、X2……请原谅，我并不想在这里上数学课，因为我厌恶那玩意儿，特别是上了大学之后，好在大二以后就再也不会有数学课了，哈哈……

Function addstar(tempword As String) As String

Dim charindex%
Dim pasteword$ '加星号后的字符串
For charindex = 1 To Len(tempword)

If Mid(tempword, charindex, 1) = " " Then '如果字符为空格

pasteword = pasteword + "*"

Else: pasteword = pasteword + Mid(tempword, charindex, 1)
End If

Next
addstar = pasteword '返回函数值

End Function

　　下面的代码很简单，并且我为它做了注释，就不再一一解释了，我只想简要的提几句，Ltrim和Rtrim只有一个参数（字符型），另外下面用到了焦点事件，我们曾在第三节中介绍过，当Text1得到焦点（GotFocus）时，清空所有的文本框，当它失去焦点（LostFocus）时，对字符进行addstar并且在Text2中显示。

Private Sub Text1_GotFocus() '但焦点于Text1

'清除所有文本框中的字符
Text1.Text = ""
Text2.Text = ""
Text3.Text = ""

End Sub

　

Private Sub Text1_LostFocus()

Dim Origionword As String
Origionword = Text1.Text
Text2.Text = addstar(Origionword)
LTrimmedword = addstar(LTrim(Origionword))
RTrimmedword = addstar(RTrim(Origionword))
LRTrimmedword = LTrim(RTrim(Origionword))

End Sub

　

Private Sub Option1_Click()

Text3.Text = LTrimmedword '显示删除左空格后的字符串

End Sub

　

Private Sub Option2_Click()

Text3.Text = RTrimmedword '显示删除右空格后的字符串

End Sub

　

Private Sub Option3_Click()

Text3.Text = LRTrimmedword '显示删除两边空格后的字符串

End Sub

运行。

　　与无线钮相对的是检查框，在同一范围内一组无线钮只能有一个被选中，而检查框则可以有多个选择，就象在添表时，性别那项只能有一个选择，而在描述你以前的职业时可以有学生、程序员、家庭教师或者什么，总之有很多选择，下面我们举一个简单的例子加以说明。

　　假设编写了一个共享软件，在让用户注册的时候你想知道你的用户使用的计算机情况，你就需要一个调查表，为了使这个调查表不止枯燥，可以在这个程序中加入一些图形。新建一个项目文件，窗体布局随意。

　　程序很简单，一共有两个框架（Frame1和Frame2），它们的Caption分别为“选择你的计算机拥有的配置”和“这是你的计算机系统”，在Frame1有四个检查框（Check1到Check4），Caption分别为“网络系统”、“鼠标”、“密码保护”和“电子邮件”，另把Check4的Enabled属性改为False，使其无效；在Frame2中放置四个图片框（Picture1到Picture4）与四个检查框向对应，请把所有图片框的BorderStyle属性设为0（无边框），它们的Picture属性请根据上图，在存放图标的目录中找到相对的图标。下面是程序代码：

Private Sub Check1_Click()

If Check1.value Then

Check4.Enabled = -1
Picture1.Visible = -1

Else: Check4.Enabled = 0
Picture1.Visible = 0
Check4.value = 0
Picture4.Visible = 0

End If

End Sub

　

Private Sub Check2_Click()

If Check2.value Then

Picture2.Visible = -1

Else: Picture2.Visible = 0

End If

End Sub

　

Private Sub Check3_Click()

If Check3.value Then

Picture3.Visible = -1

Else: Picture3.Visible = 0

End If

End Sub

　

Private Sub Check4_Click()

If Check4.value Then

Picture4.Visible = -1

Else: Picture4.Visible = 0

End If

End Sub

这个程序比我们见过的任何程序都简单，就不再做说明。

VB入门教程之九
滚动条（ScrollBar）在视窗中也是一个不可缺少的部分，由于面积所限，我们不得把屏幕上的内容滚来滚去，以显示大量的内容，这就是我们经常要用到的滚动条。但滚动条除去滚动窗口，还有一个很重要的作用――输入，想想你经常用到的一些家用电器上调节声音或别的什么东西的滑块，你把它滑向大的一方音量就会增大，而你把它滑向小的一方音量就会减小，或者一个控制左右两个音箱的均衡器，当滑块在正中央的时候，两个音箱的音量是相同的，当你把滑块偏向一方时，音箱的音量有了大小之分，在Windows操作中，我们也经常要用到类似的效果。

　　在VB中提供了两个常规的滚动条控件――Vscroll和Hscroll，分别代表垂直的和水平的滚动条，它们只不过是方向不同而已，而它们的属性，以及会发生的事件都是相同的。，滚动条有几个特殊的属性：

value属性，当滑块挪动后停在某一位置时，就改变了滚动条的value属性。

Max和Min属性，用来设置滚动条的最大值和最小值，譬如把Max设为100，把Min设为0时，滚动条的value就在0到100之间移动，当Max和Min倒置时，滚动条的方向也会相反，也就是说，当Max<Min时，原来value增加的方向就会变成相反的方向。Max和Min也可设为负值。

SmallChange和LargeChange属性，当鼠标在滚动条两头的箭头上单击时，就会把滚动条向相应的方向挪动一点，这时用到的就是SmallChange属性，当你把它设为1时，每点一下，滚动条的value就改变1；当鼠标在滚动条上点击时，用到的就是LargeChange，当设为10时，每点击一下滚动条，value就改变10。

下面我们看一个实例。

　　大家都知道，物体之所以会有颜色是因为物体表面的材料吸收了太阳光中的部分色光，而还有部分色光没被吸收而被反射回来，它就成了我们看到的颜色，黑色就是物体吸收了所有的太阳光的所有色光，没有反射颜色，所以在我们看来是黑的，而当物体反射了所有的色光，我们看到的就是白色。在计算机中，颜色的表示就是象我们刚才描述的样子，它把颜色分为红（R）、绿（G）和蓝（B）。众所周知，计算机的机器语言是使用二进制表示的，为了方便查阅我们看到的往往是十六进制代码，一个字节包括两位十六进制数字，从0－255（十六进制表示0－FF），而一个字节是由八位二进制数值表示（2^8，2的8次方），计算机中用分别用一个字节，也就是八位表示一种颜色，和在一起也就是三个字节（24位）表示所有的颜色，这就是我们平时常说的24位真彩，它一共可以组成256×256×256（2^24）种颜色，对于我们的肉眼，是根本分辨不出来相邻两个不同的颜色的，比如用FFFFFF表示白色，就好象我们刚才说的物体反射了所有的色光，相反的可以用000000表示黑色，它吸收了所有的色光，还可以用FF0000表示红色，在HTML语言中就是这样表示颜色的。

小知识：现在你可以根据你的显卡的显存来计算一下显卡在24位真彩下可以以多大的分辨率显示，计算是这样的，用显存的字节数÷3（24位色）＝显示器宽的象素数×显示器高的象素数，宽的象素数：高的象素数＝4：3，比如4兆显存，就应该是4×1024×1024÷3＝1365×1024。

在下面的小程序中，我们通过三个滚动条分别代表R、G、B，滚动滚动条，将在右边的图片框中显示相应的颜色，并且在下面的文本框中显示颜色的十六进制数值。

现在，新建一个项目文件，在Form1中布局控件，各控件属性如下表：

HsrollBar
Name Hscroll1

Index 0、1、2

（共同属性）

Max 255

Min 0

LargeChange 10

SmallChange 1

Label
Name Label1

Index 0、1、2

Index 0 Caption “红：”

Index 1 Caption “绿：”

Index 2 Caption “蓝：”

Label
Name Label2

Caption “颜色值”

TextBox
Name Text1

Text “”

PictureBox
Name Picuture1


为了把十进制数值换成十六进制数值，要使用一个叫做Hex（）的函数，它把十进制数值转化为十六进制的字符，但对于只有一位的十六进制字符，这个函数并不在高位补零，为了视觉上的正确，我设计了一个小函数帮助它给一位的十六进制字符补零.

程序代码很简单，见下：

Dim RedStr, GreenStr, BlueStr As String’RGB的字符
Dim RedNum, GreenNum, BlueNum As Integer’RGB的数值

　

Function GetColorvalue() As String

‘获得输入值
RedNum = HScroll1(0).value
GreenNum = HScroll1(1).value
BlueNum = HScroll1(2).value

RedStr = Hex(RedNum)
If Len(RedStr) < 2 Then RedStr = "0" + RedStr’补零

GreenStr = Hex(GreenNum)
If Len(GreenStr) < 2 Then GreenStr = "0" + GreenStr

BlueStr = Hex(BlueNum)
If Len(BlueStr) < 2 Then BlueStr = "0" + BlueStr

GetColorvalue = RedStr + GreenStr + BlueStr’合并

End Function

Private Sub Form_Load()

‘初始化程序
Text1.Text = GetColorvalue
Picture1.BackColor = RGB(RedNum, GreenNum, BlueNum)'RGB函数返回颜色值

End Sub

　

Private Sub HScroll1_Change(Index As Integer)

‘当滚动条被改变时
Text1.Text = GetColorvalue
Picture1.BackColor = RGB(RedNum, GreenNum, BlueNum)

End Sub

运行。

列表框（ListBox）和复合列表框（ComboBox）也是我们经常见到的视窗元素，我们从它所列示的条目中选出所需的，两种列表框只是在外观上略有不同，但从本质和操作方法来说它们是很相象的，它们也有一些特殊的属性：

List属性，你可以利于该属性象列表框或复合列表框中添加条目，但也可以在程序设计中通过AddItem方法添加。

ListCount属性，返回列表框或复合列表框中条目的数目。

ListIndex属性，表示列表框或复合列表框的第几项条目。（从0到ListCount-1）

Sorted属性，可以通过该属性对列表框或复合列表框中的条目根据字母顺序排序。

MultiSelect属性，0表示不能多选，1表示简单多选，2表示宽展多选，仅限于列表框。

Columns属性，表示条目是以一列显示还是两列显示，仅限于列表框。

Style属性：表示列表框或复合列表框以何种风格显示，二者参数不同。

举两个简单的例子。

例子一，建立一个新项目文件，在Form1上添加一个List控件，调整适当的尺寸，无需改变任何属性。填写以下代码。

Private Sub Form_Load()

With List1

.AddItem "0-Default"
.AddItem "1-Arrow"
.AddItem "2-Cross"
.AddItem "3-I-Beam"
.AddItem "4-Icon"
.AddItem "5-Size"
.AddItem "6-Size NE SW"
.AddItem "7-Size NS"
.AddItem "8-Size NW SE"
.AddItem "9-Size WE"
.AddItem "10-Up Arrow"
.AddItem "11-Hourglass"
.AddItem "12-NoDrag"
.AddItem "13-Arrow And Hourglass"
.AddItem "14-Arrow And Question"
.AddItem "15-Size All"

End With

End Sub

　

Private Sub List1_Click()

MousePointer = List1.ListIndex’这里的MousePointer是窗体全局内的属性

End Sub

当你点在不同项上面鼠标指针也会随着改变。

　

AddItem方法语法如下：

ListObject “字符串”,数值

字符串后的数值可以指定条目加入在第几个条目的位置上，如果没有的话，添加项将逐次排下去。

下面举一个复合列表框的例子，例子通过选择复合列表框中的选项来改变文本框的字体。请新建一个项目文件，在窗体中添加一个ComboBox（Combo1）和一个TextBox（Text1），添加如下代码。

Private Sub Combo1_Click()

Text1.FontName = Combo1.List(Combo1.ListIndex)

End Sub

　

Private Sub Form_Load()

With Combo1

.AddItem "宋体"
.AddItem "隶书"
.AddItem "黑体"
.AddItem "楷体"
.ListIndex = 0'把第一个条目作为初始项

End With

Text1.FontSize = 30’放大字体
Text1.FontName = Combo1.List(0)’初始字体为“宋体”

End Sub

运行。

VB入门教程之十
上一节里，我们讨论的VB的输人机制，这次我们来集中讨论VB中信息的输出。

　　输入和输出是不可分割的，人们输入的最终目的是希望计算机作出反应，任何一个程序都不可能避开这个问题，所以就算要完成一个最基本的程序，也要有输出的部分，复杂的程序更是如此。

　　在输入的一节里，我们学习的第一个输入方法是InputBox，相应的在输出中我们第一个要接触的是MsgBox（Message Box），和InputBox相似，MsgBox也是简化了的窗体，可以以函数的形式返回操作。它的基本语法是：

　　MsgBox "显示内容",按钮值,"标题"

　　通过这个函数可以产生一个标准的Windows消息框，象我们平时经常接触的“Yes/No”、“OK/Cancel”，“Retry/Abort/Ignore”等等，这些都是在按钮值中设定的，按钮值如下：

数值
含义

0
OK

1
OK和Cancel

2
Abort、Retry和Ignore

3
Yes、No和Cancel

4
Yes和No

5
Retry和Cancel


　

　　并且不同的消息可以搭配不同的图标，比如帮助文件用问号，一般提示用一个圈里一个I等等，它们也是按钮值的一部分：

数值
含义

16
表示危险

32
表示问号

48
表示警告

64
表示信息


　

　　但是如何既显示按钮也显示相应的图标呢，请看一会儿下面的例子。前面说过，MsgBox是函数，那么它就会有返回值，当你按下某个按钮就会返回一个数值，以便对用户不同动作的捕捉，返回值如下：

数值
含义

1
OK

2
Cancel

3
Abort

4
Retry

5
Ignore

6
Yes

7
No


　　说了这么多，可能你已经不知所措了，不过看过下面的例子后，相信一切都会迎刃而解。

　　首先建立一个新项目文件，并添加以下对象——一个Button（Command1），两个ComboBox（Combo1和Combo2），不要对其属性做更多的修改，只需把Command1的Caption改为“Click Me”。这个程序的目的是自由组合上面的按钮值，以显示各种消息框，并且返回按下的按钮，Combo1和Combo2分别用来选择按钮值，首先在Form_Load中初始化程序：

Private Sub Form_Load()

Combo1.AddItem "OK"

Combo1.AddItem "OK and Cancel"

Combo1.AddItem "Abort,Retry and Ignore"

Combo1.AddItem "Yes,No,Cancel"

Combo1.AddItem "Yes,No"

Combo1.AddItem "Retry,Cancel"

Combo1.ListIndex = 0

Combo2.AddItem "危险"

Combo2.AddItem "询问"

Combo2.AddItem "警告"

Combo2.AddItem "信息"

Combo2.ListIndex = 0

End Sub

ComboBox的用法已经在上一节中讨论过，在此不再赘述，ListIndex属性用来把第一个元素放在选择位置。

　　但是如何显示需要的按钮和图标呢？很简单，只需把它们相加，比如说要显示OK、Cancel按钮和警告的图标，只需把1和48相加，得到49即可，于是我们在Command1中填写这样一行：

Private Sub Command1_Click()

message = MsgBox("显示" & Combo1.List(Combo1.ListIndex) & "和" & Combo2.List(Combo2.ListIndex), Combo1.ListIndex + (Combo2.ListIndex + 1) * 16, "消息演示")

End Sub

因为图标值是从16开始的所以要把Combo2的ListIndex加1再乘以16。

小知识：按钮值并非简单的相加

按钮值并非简单的相加，我们知道，在计算机里最终的语言是机器语言，而机器语言是以0和1的二进制表示的，在这里用到的实际上不是相加，而是逻辑操作符“OR”，你知道OR和AND是怎样工作的吗？正如你所知，True And False得到False，而True Or False得到True，这是怎么形成的呢？我们有时也用0代表False，用1或－1代表True（其实，只要非零都可以代表True），而0和1在二进制中还是本身，于是True、False的运算就变成的0 和1的运算，我们可以把And叫做补0运算，把Or叫做补1运算，当用And处理两个二进制数的时候，它们逐位比较，如果相同的位上都是0或都是1则没有变化，而如果一位上是0，另一位上是1，最后结果上相应的位上就变成0。比如1010（十进制中10）And 1101（十进制中13），最后就得1000（十进制中8），相同的Or亦是如此，只不过在不同的地方补1。在位数不同时，前面补0，你可以在VB中试试看。但为什么要讲这些呢，原因是我不想让大家真的以为这个例子中就是相加，只不过碰巧它们的0和1处在不同的位置上，并且这个小知识在今后的位图操作和API操作中很有用处。

下面在来判断用户按下的按钮。

Private Sub Command1_Click()

message = MsgBox("显示" & Combo1.List(Combo1.ListIndex) & "和" & Combo2.List(Combo2.ListIndex), Combo1.ListIndex + (Combo2.ListIndex + 1) * 16, "消息演示")

Select Case message

Case 1

MsgBox "你按下了OK钮"

Case 2

MsgBox "你按下了Cancel按钮"

Case 3

MsgBox "你按下了Abort按钮"

Case 4

MsgBox "你按下了Retry按钮"

Case 5

MsgBox "你按下了Ignore按钮"

Case 6

MsgBox "你按下了Yes按钮"

Case 7

MsgBox "你按下了No按钮"

End Select

End Sub

运行程序。


到了现在，经过十节的VB入门系列教程，相信你已经对Visual Basic有了一定的了解，希望你能继续努力。另外，希望你能继续支持“VB学堂”。“VB学堂”其它栏目还有很多重要的文献资料，能帮助你解决实际编程中遇到的种种困难。Thank You！